Как батником переименовать файлы?

хочу написать bat файл по переименованию всех файлов mp3 в директории в последовательные имена.
Но напоролся на проблемку.
------------------------------
Пример 1.
FOR %%x IN (*.mp3) DO (
echo %%x
)
------------------------------
выдаст список всех mp3 файлов в директории.
------------------------------
Пример 2.
FOR /L %%x IN (1, 1, 5) DO (
echo %%x
)
------------------------------
выдаст последовательность 1,2,3,4,5

а вот объеденить не могу вместе.

Пытался что-то вроде так.

SET x=1
FOR %%x IN (*.mp3) DO (
SET x=%%x+1
echo %%x
)

не получается...

P.S. и вообще какая разница между %a, %%a и %a% ?

batch язык не поддерживает численных значений, только строки
%a - переменная, но с командной строки
%%a - переменная в batch-файле
%a% - переменная окружения (например %PATH%)
вообще лучше используй perl
да, и часто под виндой9x может не хватать памяти под переменныые и set может не работать
лечится ключами command.com
(щас не помню какими)
я хотел сказать bat под NT. там поддерживаются и числа и вычисления и еще куча примочек.
Я написал переменовалку всех файлов в текущей директории! Дарю всем!

Использование:

например были файлы типа
beethoven- ode to love (Techno Remix).mp3
Brittany Spears - (I can't get no) Satisfaction.mp3
Christmas - Funny - A Christmas Story - Chinese Carols.mp3
Christmas - Funny - Simpsons - Jingle Bells.mp3
Classical - Duel Of The Fates (Techno Remix).mp3
Crystal Method - Come2gether {Mortal Kombat - More Kombat}.mp3
Darude - 08 - Drums Of New York.mp3
Darude - Feel the Beat (Extended mix).mp3
Dido - My Lover's gone.mp3

Вводим mrename.bat myfile

все файлы в текущей директории будут переименованы в последовательность

myfile1001.mp3
myfile1002.mp3
myfile1003.mp3
myfile1004.mp3
myfile1005.mp3
myfile1006.mp3
myfile1007.mp3

и будет создан скрытый файл undo.bat


------------------ mrename.bat ------------------
@echo off
rem * Windows NT only
VER | FIND "Windows NT" > NUL
IF ERRORLEVEL 1 GOTO syntax
if "%1"=="" goto syntax
set count=0
echo rem UNDO FILE > undo.bat
attrib +H undo.bat
FOR /f "tokens=*" %%a in ('dir /on /b *.*') do (
set /a count+=1
set /a s=count+1000
call echo ren %1%%s%%.* "%%a" >> undo.bat
call ren "%%a" %1%%s%%.*
)
rem Rename file1001.* to file0001.*
rem FOR %%a in (%11*.*) do (
rem ren %%a %10???.*
rem )
echo %count% files renamed
goto end
:syntax
echo Mass File Rename for Windows NT4 only.
echo Syntax:
echo Author: Nikolai Ivanov aka TTL 2001 USA ttl@irtel.ru
echo mrename.bat prefix
:end
set count=
set s=

(c) Nikolai Ivanov


TopList Rambler's Top100